关于移动荷载的命令流

/solu
D,1,uy, , , , ,ux
D,2,uy,
antype,subst
tim=0
delt=1
timint,on
*do,i,0,64,1
tim=tim+1
time=tim
fdele,all,all
nsel,all
nsel,s,loc,x,(64+i)*0.5
f,all,fy,-220000
nsel,all
nsel,s,loc,x,(64+i-3)*0.5
f,all,fy,-220000
nsel,all
nsel,s,loc,x,(64+i-6)*0.5
f,all,fy,-220000
nsel,all
nsel,s,loc,x,(64+i-9)*0.5
f,all,fy,-220000
nsel,all
nsel,s,loc,x,(64+i-12)*0.5
f,all,fy,-220000
nsel,all
nsel,s,node,,66+i-15,1,-1
f,all,fy,-46000
nsel,all
nsubst,1
outres,all,all
solve
*enddo
finish
/post26
axlab,y,uy
nsol,2,34,u,y,bx34
nsol,3,66,u,y,bx66
nsol,4,98,u,y,bx98
plvar,2,3,4

关于移动荷载的命令流
*SET,long,32      !梁长度32
*SET,ne,100        !单元数量100
*SET,detl,long/ne   !定义单元长度
*SET,ii,ne+1      !节点数量100+1
*SET,f,1000      !集中力1000
*SET,v,120        !移动速度120km/h
*SET,dett,detl/v*3.6 !每个单元上的时间
!*SET,w,10
!*SET,w,5
*SET,w,1  
! 建模
/config,nres,2000
/prep7
et,1,beam3     ！ 定义单元属性
r,1,0.1,0.0001/12,0.1
mp,ex,1,207e9
mp,prxy,1,0.3
mp,dense,1,2000


! 循环命令创建节点
*do,i,1,ii,1
n,i,(i-1)*detl
*enddo



!创建单元
*do,i,1,ne
e,i,i+1
*enddo
finish


!加载求解
/sol
d,1,all
d,101,all

ANTYPE,4            !分析类型为瞬态分析
TRNOPT,FULL         !解析方法为full法
OUTRES,BASI,ALL     !输出每一子步的基本结果
KBC,1.0             !指定荷载步变化为阶越
TIMINT,0            !不考虑瞬态影响
NSUBST,4,8,0        !子步数为4步，最大不超过8步
TIME,1e-10          !加载结束时间1e－10s
sstif,on            !应力钢化效应打开
ACEL,0,9.8,0,       !施加y方向的加速度9.8

solve

timint,on           !考虑瞬态影响


!施加常力并求解

*do,ii,1,101+8,1

outres,all,all    !施加移动荷载
time,ii*dett
nsubst,5
*if,ii,lt,8,then
fdele,all,all
nsel,s,loc,x,(ii-1)*detl
f,all,fy,-f
allsel
solve
  *elseif,ii,lt,101
  fdele,all,all
  nsel,s,loc,x,(ii-1)*detl
  nsel,a,loc,x,(ii-1-7)*detl
  f,all,fy,-f
  allsel
  solve
*else
fdele,all,all
nsel,s,loc,x,(ii-7-1)*detl
f,all,fy,-f
allsel
solve
*endif
*enddo
finish

!施加匀速简谐力并求解

*do,ii,1,101+8,1
outres,all,all    !施加移动荷载
time,ii*dett
nsubst,5
*if,ii,lt,8,then
fdele,all,all
nsel,s,loc,x,(ii-1)*detl
f,all,fy,-f*cos(w*ii*dett)
allsel
solve
  *elseif,ii,lt,101
  fdele,all,all
  nsel,s,loc,x,(ii-1)*detl
  nsel,a,loc,x,(ii-1-7)*detl
  f,all,fy,-f*cos(w*ii*dett)
  allsel
  solve
*else
fdele,all,all
nsel,s,loc,x,(ii-7-1)*detl
f,all,fy,-f*cos(w*ii*dett)
allsel
solve
*endif
*enddo
finish


/POST26
NSOL,2,51,U,Y,UY_2                  ! 定义第二个变量为UY_2,值为50号节点Y方向的位移
XVAR,1                ! 定义时间变量为坐标横轴
PLVAR,2                ! 输出位移图
DERIV,3,2,1,,,,1         ! 将位移对时间求导，得到速度，存为变量3
PLVAR,3                ! 输出速度图
FINISH